För att skapa ett bildspel i Exceldiagram behöver du använda VBA makro. Här är ett VBA-makro för Excel som visar ett helskärmsläge bildspel med alla de inbäddade diagram i det aktiva kalkylbladet.

VBA Makro för bildspel

Sub ChartSlideShow()
    Dim Cht As ChartObject
    Dim UserSheet As Worksheet
    Set UserSheet = ActiveSheet
    Application.DisplayFullScreen = True
    Application.DisplayAlerts = False

    For Each Cht In UserSheet.ChartObjects
        Application.ScreenUpdating = False
        ' Delete old chart sheet if it exists
        On Error Resume Next
        Charts("ChartTemp").Delete
        On Error GoTo 0
        ' Copy embedded chart and move it
        UserSheet.Activate
        Cht.Chart.ChartArea.Copy
        ActiveSheet.Paste
        ActiveChart.Location Where:=xlLocationAsNewSheet, _
           Name:="ChartTemp"
        ' Show the chart sheet and prompt for next one
        Application.ScreenUpdating = True
        If MsgBox("OK for next chart, Cancel to stop.", _
          vbQuestion + vbOKCancel) = vbCancel Then Exit For
     Next Cht
     ' Clean up
     On Error Resume Next
     Charts("ChartTemp").Delete
     On Error GoTo 0
     Application.DisplayFullScreen = False
     Application.DisplayAlerts = True
     UserSheet.Activate
End Sub

Bara kopiera och klistra in koden till ett VBA-modul. Sedan aktivera ett
kalkylblad som innehåller inbäddade diagram och utföra ChartSlideShow makro.
Det ändrar inget i din ursprungliga diagram.

Observera att du kan skapa text-only diagram genom att ta bort bilden i
ett diagram objekt.
Sätt sedan i en form och lägg till lite text.
Du kan också visa bilder genom att ta bort tabellen och infoga en bild.

Detta fungerar i både Excel 2003 och Excel 2007 men det ser lite bättre
i Excel 2007.

Ordningen på bilderna bestäms av z-ordningen på listorna i kalkylbladet.
Du kan ändra z-ordning genom att högerklicka på diagrammet objektet,
och med hjälp av "skicka vidare" eller "skicka bakåt"-kommando.